#!/usr/bin/perl -w

#*********#
# MODULES #
#*********#
use strict;
no strict "subs";
no strict "refs";
use XML::Parser;
use Getopt::Std;
use Carp;
use HTML::Entities;
use vars qw($AUTOLOAD);

#***********#
# CONSTANTS #
#***********#
my %article = (create_date => '',
	       revise_date => '',
	       issuenum    => '',
	       abstract    => '',
	       title       => ''
	       );

my %author_dir = ('3d'       => '',
		  'dhtml'    => '',
		  'graphics' => 'greats/',
		  'html'     => '',
		  'js'       => '',
		  'perl'     => 'tutorial/',
		  'xml'      => ''
		  );

#*********#
# GLOBALS #
#*********#
my $pages = 0;
my $pagecnt = 1;

# get tutorial filename
my %opts = ();
getopt('f', \%opts);
&usage unless $opts{f};
&usage unless -e $opts{f};

#***************************************************#
# -Count the number of pages we have in the article #
#***************************************************#
# parser tutorial file and get page count
my $p = new XML::Parser;
$p->setHandlers(Start => \&pages);
$p->parsefile($opts{f}) || die "Cannot parse $opts{f}: $!\n";
undef $p;
print STDOUT "Found $pages pages\n";

open (STDERR, ">/dev/null");
select(STDERR);

# -generate HTML, second pass #
$p = new XML::Parser;

# set handlers
$p->setHandlers(Char    => \&handle_char,
		Start   => \&handle_start,
		End     => \&handle_end);
# get filename pased from the command line
$p->parsefile($opts{f}) || die "Cannot parse $opts{f}: $!\n";

#*************#
# SUBROUTINES #
#*************#
sub banner_ad_top {
    print <<HTML;
<p CLASS="wrAd"><center>
<!-- START AD -->
<!-- START AD -->
<!--#config errmsg="" -->
<!--#include
virtual="/html.ng/site=internetcom&size=468x60&PagePos=10&channel=_CHANNEL_&content_site=_SITE_&feature=_FEATURE_" -->
<!-- END AD -->
</center></p>
HTML
}

sub banner_ad_bottom {
    print <<HTML;
<p CLASS="wrAd"><center>
<!-- START AD -->
<!-- START AD -->
<!--#config errmsg="" -->
<!--#include
virtual="/html.ng/site=internetcom&size=468x60&PagePos=20&channel=_CHANNEL_&content_site=_SITE_&feature=_FEATURE_" -->
<!-- END AD -->
</center></p>
HTML
}

sub button_bar {
    my $label = "$author_dir{$article{'productname'}} $article{'issuenum'}";
    $label =~ s#/##;

    # first page
    if ($pagecnt == 1) {
print <<HTML;
<table border="0" align="center" width="100%">
<tr><td align="left"><b><a HREF="/">home</a> / <a HREF="/experts/">experts</a> / <a HREF="/$article{'productname'}/">$article{'productname'}</a> / $label</b></td>
<td align="right">
HTML

    # page 2 - x
    } else {
	print <<HTML;
<table border="0" align="center" width="100%">
<tr><td align="left"><b><a HREF="/">home</a> / <a HREF="/experts/">experts</a> / <a HREF="/$article{'productname'}/">$article{'productname'}</a> / <a HREF="/$article{'productname'}/$author_dir{$article{'productname'}}$article{'issuenum'}">$label</a></b></td>
<td align="right">
HTML
    }

    # print the page buttons
    for (my $i = 1; $i <= $pages; $i++) {
	my $filename = ($i == 1 ? "index.html" : "$i.html");
	if ($i == $pagecnt) {
	    print "<img src=\"../../art/b_center.gif\" width=\"18\" height=\"18\" border=\"0\">";
	} elsif ($i < $pagecnt) {
	    print "<a href=\"$filename\">";
	    print "<img src=\"../../art/b_left.gif\" width=\"18\" height=\"18\" border=\"0\"></a>";
	} elsif ($i > $pagecnt) {
	    print "<a href=\"$filename\">";
	    print "<img src=\"../../art/b_right.gif\" width=\"18\" height=\"18\" border=\"0\"></a>";
	}
    }

    print <<HTML;
</td></tr></table>
HTML
}

sub footer {
    my $filename = shift;
    my $label = "$author_dir{$article{'productname'}} $article{'issuenum'}";
    $label =~ s#/##;

    print <<HTML;
<!-- START FOOTER CODE -->
<P ALIGN=CENTER><A HREF="http://www.internet.com/" TARGET="_top"><IMG SRC="/img/URL.gif" border=0 WIDTH=161 HEIGHT=18 ALT="http://www.internet.com"></A></P>
<DIV class="footer">
<P ALIGN=CENTER><small>Produced by <A HREF="/cgi-bin/suggest.cgi">$article{author_first} $article{author_last}</A><BR>
<!--#include virtual="/scripts/copyright.txt"-->
All Rights Reserved. <A HREF="http://www.internet.com/corporate/legal.html">Legal Notices.</A><BR>

<!-- END CODE -->
Created: $article{'create_date'}<BR>
Revised: $article{'revise_date'}</P>

<P ALIGN=CENTER>URL: http://www.webreference.com/$article{'productname'}/$author_dir{$article{'productname'}}$article{'issuenum'}/$filename</P>
</DIV>
</body></html>
HTML
}

sub handle_char {
    my ($self,$text) = @_;
    
    # grab article header stuff
    if ($self->within_element("artheader")) {
	$article{create_date} .= $text if $self->current_element eq "date";
	$article{revise_date} .= $text if $self->current_element eq "pubdate";
	$article{issuenum} .= $text if $self->current_element eq "issuenum";
	$article{title} .= $text if $self->current_element eq "title";
	$article{abstract} .= $text if $self->current_element eq "abstract";
	$article{productname} .= $text if $self->current_element eq "productname";
    }

    # grab author stuff
    if ($self->within_element("author")) {
	$article{author_first} = $text if $self->current_element eq "firstname";
	$article{author_last}  = $text if $self->current_element eq "surname";
    }
    
    # print character data
    encode_entities($text);
    print $text
	unless ($self->within_element('artheader') 
		|| $self->within_element('author')
		|| $self->within_element('keywordset')
		|| $self->within_element('legalnotice')
		|| $self->within_element('abstract')
		);
}

#sub handle_default {
#    encode_entities($_[1]);
#    print "$_[1]";
#}

sub handle_end {
    &{"$_[1]_"}(@_);
}

sub handle_start {
    &{$_[1]}(@_);
}

sub pages { return $pages++ if $_[1] eq 'sect1'; }

sub para  { print "<p class=\"para\">"; }
sub para_ { print "</p>\n"; }

sub programlisting  { print "<pre class=\"programlisting\">"; }
sub programlisting_ { print "</pre>\n";}

sub sect1  {
    my $filename = ($pagecnt == 1 ? "index.html" : "$pagecnt.html");
    print STDOUT "Writing $filename\n";
    open(FILE,">$filename") || die "Cannot open $filename: $!\n";
    select(FILE);

    print <<HTML;
<html><head>
<title>$article{'title'}</title>
<link rel="STYLESHEET" type="text/css" href="../tutorial.css"></link>
</head>
<body BGCOLOR="#FFFFFF" TEXT="#000000" LINK="#0033FF" VLINK="#660099">
HTML

    &banner_ad_top;
    print <<HTML;
</center></p>
<p CLASS="wrNav"><center><a HREF="/art/index.map"><img SRC="/art/bn_wrl_sm.gif" WIDTH="468" HEIGHT="18" ALT ISMAP BORDER="0"></a></p>
</center>
HTML
    
    &button_bar;
    print "<blockquote>\n"; 
}

sub sect1_ { 
    my $filename = ($pagecnt == 1 ? "index.html" : "$pagecnt.html");
    print <<HTML;
</blockquote><div align="center"></div>
<BR>
HTML

    &button_bar;
    &banner_ad_bottom;
    &footer($filename);

    close(FILE);
    select(STDERR);
    $pagecnt++;
}

sub sect2  { }
sub sect2_ { }

sub title  { 
    my ($self, $el, %attribs) = @_;
    if ($self->within_element('sect2')) {
	print "<H3 class=\"sect2\">\n";
    } elsif ($self->within_element('sect1')) {
	print "<H1 align=\"center\" class=\"title\">$article{'title'}</H1>\n";
	print "<H2 align=\"center\" class=\"sect1\">\n";
    }
}
sub title_ {
    my ($self, $el) = @_;
    if ($self->within_element('sect2')) {
	print "</H3>\n";
    } elsif ($self->within_element('sect1')) {
	print "</H2>\n";
    }
}

sub ulink  {
    my ($self, $el, %attribs) = @_;
    my $url = $attribs{'href'};
    print "<a href=\"$url\">";
}
sub ulink_ { print "</a>"; }

sub usage {
    print "\nUsage: webref_generate.pl -f <tutorial.docbook>\n";
    exit;
}

sub AUTOLOAD {
    my @args = @_;
    my $self = shift;
    my $type = ref($self) || croak "$self is not an object\n";
    my $name = $AUTOLOAD;
    $name =~ s/.*://;

    # ignore if within these elements
    return if ($self->within_element('artheader') 
	       || $self->within_element('author')
	       || $self->within_element('keywordset')
	       || $self->within_element('legalnotice')
	       || $self->within_element('abstract')
	       );
    
    # ignore if we are these elements
    return if ($args[1] eq 'article'
	       || $args[1] eq 'abstract'
	       || $args[1] eq 'artheader'
	       );
    
    if ($name =~ /_$/) {
	print "</span>";
    } else {
	print "<span class=\"$name\">";
    }
}